I play DROD on a 32bit Windows 7 machine
I keep a plain text notes file to record my deep insights for possible sharing with others. I keep screenshots of memorable room states, and often, too often, I have the Caravel forum pages open .... you can guess which forum.
I play most holds in DROD 3, but the newer ones in DROD 4.
Sometimes my machine is VPN'ed in to a corporate network and I need to set the http proxy.
I'm sharing the script I use to launch Drod, along with an editor, directory browser, and web browser to the forums.
Usage: drod {3|4} [proxy] [solo]
launch DROD engine 3 or 4 along with notes,
screenshots directory, and forum help
proxy sets http_proxy to http://192.234.123.34:80
solo does not launch editor, screenshot browser, or
web page to Caravel Forums.
DROD launcher 1.0 24-SEP-13
Click here to view the secret text
×
@echo off
rem -----------------------------------------------------------------------+
rem File: drod.cmd
rem Auth: Karl Popper (Caravel ID: karlpopper)
rem Date: 2011-03-16
rem Description:
rem Script to invoke DROD and a notes file, and browse the
rem screen-shots directory, and view the Caravel forums,
rem with an option to use a web proxy.
rem see: http://forum.caravelgames.com/viewtopic.php?TopicID=5716&page=0#60690
rem History:
rem 2013-09-24 - 1.0 - obfuscate personal and corporate identity prior to publication
rem 2013-09-19 - 0.9 - Launch notepad, explorer and forums, and allow non-proxy mode
rem 2011-04-01 - 0.6 - added cls after DROD invocation to hide tracks
rem 2011-03-16 - 0.5 - initial version with web proxy
rem -----------------------------------------------------------------------+
setlocal
set VERSION=1.0 24-SEP-13
if not "%BATCH_ECHO%"=="" echo on
rem -------------------------------------+
rem Script customization
rem -------------------------------------+
set DROD3_EXE=C:\Games\DROD - The City Beneath\drod.exe
set DROD4_EXE=C:\Games\DROD 4 - Gunthro and the Epic Blunder\drod.exe
set EDITOR=notepad++
set WEB_BROWSER_DIR=C:\Program Files\Mozilla Firefox
set WEB_BROWSER_EXE=firefox.exe
set WEB_PROXY=http://192.34.56.78:80
set NOTES_FILE=C:\Users\Karl\Documents\My Dropbox\Software\Caravel\Engine3.0\Data\Homemade\drod.notes.2011.txt
set SCREENSHOTS_DIR=C:\Users\Karl\Documents\My Dropbox\Software\Caravel\Engine3.0\Data\Homemade
set CARAVEL_FORUMS=http://forum.caravelgames.com/
rem -------------------------------------+
:parmcheck
if "%1"=="" goto Usage
set DROD_VERSION=3
:parse
if "%1"=="" goto main
set PARAM_OK=
if "%1"=="3" (set DROD_VERSION=%1& shift& set PARAM_OK=1)
if "%1"=="4" (set DROD_VERSION=%1& shift& set PARAM_OK=1)
if "%1"=="proxy" (set HTTP_PROXY=%WEB_PROXY%& shift& set PARAM_OK=1)
if "%1"=="solo" (set SOLO=1& shift& set PARAM_OK=1)
if "%PARAM_OK%"=="" (echo Error: bad parameter "%1"& goto usage)
goto parse
:main
echo Drod launcher %VERSION%
if "%SOLO%"=="1" goto solo
echo Starting editor for %NOTES_FILE%
start %EDITOR% "%NOTES_FILE%"
echo Starting explorer for: %SCREENSHOTS_DIR%
start explorer "%SCREENSHOTS_DIR%"
echo Starting browser for forums at %CARAVEL_FORUMS%
rem Boy, is microsoft arcane sometimes
rem see http://stackoverflow.com/questions/154075/using-the-dos-start-command-with-parameters-passed-to-the-started-program
start /D "%WEB_BROWSER_DIR%" %WEB_BROWSER_EXE% -new-window %CARAVEL_FORUMS%
:solo
echo Starting DROD %DROD_VERSION% ...
if "%DROD_VERSION%"=="3" goto drod3
if "%DROD_VERSION%"=="4" goto drod4
goto usage
:drod3
"%DROD3_EXE%"
goto clearend
:drod4
"%DROD4_EXE%"
goto clearend
:usage
echo.
echo -----------------------------------------------------------
echo Usage: %0 {3^|4} [proxy] [solo]
echo.
echo launch DROD engine 3 or 4 along with notes,
echo screenshots directory, and forum help
echo.
echo proxy sets http_proxy to %WEB_PROXY%
echo solo does not launch editor, screenshot browser, or
echo web page to Caravel Forums.
echo.
echo Drod 3: %DROD3_EXE%
echo Drod 4: %DROD4_EXE%
echo Notes File: %NOTES_FILE%
echo Screenshots: %SCREENSHOTS_DIR%
echo Forums: %CARAVEL_FORUMS%
echo.
echo DROD launcher %VERSION%
echo -----------------------------------------------------------
echo.
goto end
:clearend
cls
:end
endlocal
rem -----------------------------------------------------------------------+
rem end of file drod.cmd
rem -----------------------------------------------------------------------+
You'll need to customize the variables at the head of the
script for your environment.
____________________________
76th SkyWatcher
When the only tool you have is a Really Big Sword, all problems start to look like Giant Roaches